macrocell_office_iot/espsens/espsens.ino

/* ESP8266 environmental sensor project
 *  
 *  This firmware provides features to use the NodeMCU ESP12 unit as an environmental sensor.
 *  Currently supported is the DHT22 temperature and humidity sensor. 
 *  The sensor is to be connected to pin D2 of the NodeMCU ESP12 breakout card pin.
 *  
 *  (C) 2019 Macrocell - Environmental sensing solutions
 *   proudly presented by Macrocell - FPGA Innovators
 */

#include <ESP8266WiFi.h>
#include <Wire.h>
#include <PubSubClient.h>
#include "DHT.h"
#include "configuration.h"

#define TOPIC_BASE "sensor/" SENSOR_ID "/"
#define TOPIC_TEMP TOPIC_BASE "temperature"
#define TOPIC_HMID TOPIC_BASE "humidity"
#define TOPIC_HEAT TOPIC_BASE "heat_index"
#define TOPIC_ABHU TOPIC_BASE "abs_humidity"

#define DIFF_TEMP 0.3 // sensor has only 0.5°C accuracy, triggering on less is ludicrous
#define DIFF_HMID 1.5 // humidity doesn't change that much anyways
#define DIFF_HEAT 0.3 // this one's actually quite active
#define DIFF_ABHU 0.2 // small changes mean quite something

float hmid = 0; // humidity
float hmid_r = 0; // humidity
float abhu = 0; // absolute humidity
float abhu_r = 0; // absolute humidity
float temp = 0; // temperature
float temp_r = 0; // temperature
float heat = 0; // heat index
float heat_r = 0; // heat index

#define DHTPIN 4     // Digital pin connected to the DHT sensor
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);

void setup() {
  Serial.begin(SERIAL_BAUDRATE);
  pinMode(LED_BUILTIN, OUTPUT); 
  digitalWrite(LED_BUILTIN, LOW);
  setup_wifi();
  client.setServer(MQTT_SERVER, MQTT_PORT);
  dht.begin();
}

void setup_wifi() {
  delay(10);
  // Connect to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(WIFI_SSID);

  WiFi.begin(WIFI_SSID, WIFI_PW);
  WiFi.mode(WIFI_STA);

  // blink LED fast until WiFi is connected
  while (WiFi.status() != WL_CONNECTED) {
    delay(200);
    digitalWrite(LED_BUILTIN, HIGH);
    Serial.print(".");
    delay(200);
    digitalWrite(LED_BUILTIN, LOW);
  }

  // WiFi connected
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void reconnect() {
  // Loop until reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect(MQTT_CLIENT, MQTT_USER, MQTT_PW)) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      digitalWrite(LED_BUILTIN, HIGH);
      // Wait 5 seconds before retrying
      delay(4000);
      digitalWrite(LED_BUILTIN, LOW);
      delay(1000);
    }
  }
}

bool checkVariation(float newValue, float prevValue, float maxDiff) {
  return !isnan(newValue) &&
         (newValue < prevValue - maxDiff || newValue > prevValue + maxDiff);
}

bool checkPlausibility(float newValue, float prevValue, float maxDiff) {
  return (newValue < prevValue + (maxDiff * 10) || newValue > prevValue - (maxDiff * 10));
}

long lastMsg = 0;
long lastSent = 0; 
bool published = false;
bool forcePublish = false;

bool publish (String desc, char *topic, float val, float &lastVal, float diff, bool force){
  bool ret = false;
  Serial.println("Sample " + desc + ": " + String(val).c_str());
  if (checkVariation(val, lastVal, diff) or force) {
    Serial.println("Sufficient variation on " + desc + ": " + String(val).c_str());
    if (checkPlausibility(val, lastVal, diff) or force) {
      Serial.println("Value published");
      client.publish(topic, String(val).c_str(), true);
      ret = true;
    } else {
      Serial.print("** ERROR: Value out of bounds, not published. Last value :");
      Serial.println(String(lastVal).c_str());
    }
    lastVal = val;
  }
  return ret;
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();
  digitalWrite(LED_BUILTIN, HIGH);

  long now = millis();
  if (now - lastMsg > OPERATION_PERIOD / 2) {
    if (OPERATION_BLINK_EN) {digitalWrite(LED_BUILTIN, LOW);}
  }
  if (now - lastMsg > OPERATION_PERIOD) {
    lastMsg = now;
    if (OPERATION_BLINK_EN) {digitalWrite(LED_BUILTIN, HIGH);}

    hmid = dht.readHumidity();
    temp = dht.readTemperature();
  
    if (!isnan(hmid) && !isnan(temp)){
      abhu = (6.112 * ( pow(2.71828, ((17.67 * temp) / (temp + 243.5))) * hmid * 2.1674)) / (273.15 + temp);
      heat = dht.computeHeatIndex(temp, hmid, false);
    }
 
    published = false;
    if (lastSent > FORCE_PERIOD) {
      Serial.println(F("Forcing a publish of all values"));
      forcePublish = true;
      lastSent = 0;
    }

    published += publish("temperature", TOPIC_TEMP, temp, temp_r, DIFF_TEMP, forcePublish);
    published += publish("humidity", TOPIC_HMID, hmid, hmid_r, DIFF_HMID, forcePublish);
    published += publish("heat index", TOPIC_HEAT, heat, heat_r, DIFF_HEAT, forcePublish);
    published += publish("absolute humidity", TOPIC_ABHU, abhu, abhu_r, DIFF_ABHU, forcePublish);    
    
    if (published == false) {
      lastSent = lastSent + 1;
    } else {
      lastSent = 0;
    }
    
    forcePublish = false;
  }
}