GNOME Fractal adapted to work with Thales Citadel (PKGBUILD for ArchLinux)
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 

45 lines
1.5 KiB

# Maintainer: Markus Koch <markus@notsyncing.net>
pkgname=fractal-citadel
_gitname=fractal
pkgver=r2331.f9861e4b
pkgrel=1
pkgdesc="GNOME Fractal adapted to work with Thales Citadel"
arch=('i686' 'x86_64' 'aarch64')
license=('GPL3')
url="https://gitlab.gnome.org/GNOME/fractal"
depends=('gtk3' 'libhandy' 'gtksourceview3' 'gstreamer' 'gst-plugins-base-libs' 'gst-plugins-bad' 'gst-editing-services' 'gst-libav' 'gspell')
optdepends=('gnome-keyring: secrets service')
conflics=('fractal' 'fractal-git')
provides=('fractal')
makedepends=('rust' 'gst-editing-services' 'pkg-config' 'git' 'meson')
source=("git+https://gitlab.gnome.org/World/fractal.git" "0001-Use-AccessToken-auth-for-media.patch")
md5sums=('SKIP' 'SKIP')
pkgver() {
cd "${srcdir}/${_gitname}/"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
# Run vanilla build to download all crates
cd "${srcdir}/${_gitname}/"
arch-meson . _build
ninja -C _build
# Then patch the API files
cd _build/target/cargo-home/git/checkouts/ruma-*/*/ruma-client-api/
patch -p1 < ${srcdir}/0001-Use-AccessToken-auth-for-media.patch
cd "${srcdir}/${_gitname}/"
# Force rebuild by "changing" a source file, which will also cause the
# dependencies that were downloaded with the first ninja command, and then
# modified through the patches, to be rebuilt.
touch fractal-gtk/src/main.rs
ninja -C _build
}
package() {
cd "${srcdir}/${_gitname}/"
DESTDIR="${pkgdir}" ninja -C _build install
}