mdiary/dist/archlinux/PKGBUILD

# $Id$
# Maintainer: Markus Koch <markus@notsyncing.net>

pkgname=mdiary-git
pkgver=20180708.137.017e6e8
pkgrel=1
pkgdesc='A viewer for a file based diary with entries written in markdown.'
arch=('i686' 'x86_64')
url='https://git.notsyncing.net:8080/markus/mdiary'
license=('GPL')
depends=('gtk3' 'glib2' 'webkit2gtk')
makedepends=('cmake')
source=("$pkgname"::"git+https://git.notsyncing.net/markus/mdiary.git")
sha1sums=('SKIP')

pkgver () {
	_date=`date +"%Y%m%d"`
	cd "${srcdir}/${pkgname}"
	echo "$_date.$(git rev-list --count master).$(git rev-parse --short master)"
}

prepare() {
	cd $pkgname
	git submodule init
	git submodule update
}

build() {
	cd "$srcdir/$pkgname"

	cmake .

	make
}

package() {
	cd "$srcdir/$pkgname"

	make DESTDIR="${pkgdir}" install

	install -D -m644 "$srcdir/$pkgname/dist/mdiary.svg" \
		"$pkgdir/usr/share/icons/hicolor/scalable/apps/mdiary.svg"
	install -D -m644 "$srcdir/$pkgname/dist/mdiary.desktop" \
		"$pkgdir/usr/share/applications/mdiary.desktop"
}