wip: eth

trashernet/trashernet_eth.vhd

@@ -0,0 +1,128 @@
+-- -------------------------------------------------------------------------- --
+--               TRASHERNET - A Trashy Ethernet Stack for FPGAs               --
+-- -------------------------------------------------------------------------- --
+-- trashernet_mac_top.vhd : Ethernet OSI Layer 2, Data Link, filtered
+--   Implements header creation, parsing, and protocol arbitration.
+-- -------------------------------------------------------------------------- --
+-- Author       : Markus Koch <markus@notsyncing.net>
+-- Contributors : None
+-- License      : Mozilla Public License (MPL) Version 2
+-- -------------------------------------------------------------------------- --
+
+library ieee;
+use ieee.std_logic_1164.all;
+use ieee.numeric_std.all;
+
+use work.trashernet_pkg.all;
+
+entity trashernet_eth is
+	generic(
+		F_CLK                 : in integer; -- Clock frequency of design IF
+		F_CLK_PHY             : in integer; -- PHY clock (expected to be faster than F_CLK)
+		ETHERNET_II_PROTOCOLS : ethernet_ii_protocol_vector := ETHERNET_II_PROTOCOLS_NONE
+	);
+	port(
+		-- Global
+		clk             : in  std_logic; -- Global clock
+		rst             : in  std_logic; -- Asynchronous reset
+
+		-- MAC application interface
+		mac_out         : in  mac_out_t; -- MAC application IF (out of MAC)
+		mac_in          : out mac_in_t; -- MAC application IF (into MAC)
+
+		-- Configuration
+		config          : in  configuration_t; -- Global Trashernet configuration
+
+		-- Ethernet 802.3 application interface
+		ethernet_i_out  : out ethernet_i_out_t; -- Ethernet 802.3 IF (out from MAC)
+		ethernet_i_in   : in  ethernet_i_in_t                                    := ETHERNET_I_IN_UNUSED; -- Ethernet 802.3 IF (out from MAC)
+
+		-- Ethernet II application interface
+		ethernet_ii_out : out ethernet_ii_out_vector(ETHERNET_II_PROTOCOLS'range); -- Ethernet II IF (out from MAC)
+		ethernet_ii_in  : in  ethernet_ii_in_vector(ETHERNET_II_PROTOCOLS'range) := (others => ETHERNET_II_IN_UNUSED) -- Ethernet II IF (into MAC)
+	);
+end entity trashernet_eth;
+
+architecture rtl of trashernet_eth is
+begin
+	rx : block
+		signal sel                     : integer range ethernet_ii_out'low to ethernet_ii_out'high;
+		signal mac_destination_matches : std_logic;
+	begin
+
+		mac_destination_matches <= '1' when --
+		                           ((mac_out.rx_header.mac_destination = (x"FF", x"FF")) or --
+		                            (mac_out.rx_header.mac_destination = config.mac_address)) else
+		                           '0';
+
+		mux : process(clk, rst) is
+		begin
+			if rst then
+
+			elsif rising_edge(clk) then
+				if mac_out.rx_mac_header_rcv then
+					if mac_destination_matches then
+						if (unsigned(std_logic_vector'(mac_out.rx_header.mac_ethertype(0) & mac_out.rx_header.mac_ethertype(1))) < 1500) then -- Ethernet 802.3 Frame
+							null;       -- TODO: Not yet implemented
+
+						else            -- Ethernet II Frame
+							for i in ETHERNET_II_PROTOCOLS'range loop
+								if (mac_out.rx_header.mac_ethertype = ETHERNET_II_PROTOCOLS(i).ethertype) then
+									sel <= i;
+								end if;
+							end loop;
+						end if;
+					end if;
+				end if;
+			end if;
+		end process mux;
+
+		-- Shared fields in the Ethernet application interface
+		shared_fields : for i in ethernet_ii_out'range generate
+			ethernet_ii_out(i).rx_mac_address <= mac_out.rx_header.mac_source;
+			ethernet_ii_out(i).rx_data        <= mac_out.rx_mac_data;
+			ethernet_ii_out(i).rx_data_valid  <= mac_out.rx_mac_valid when sel = i;
+		end generate shared_fields;
+	end block rx;
+
+	tx : block
+		type state_t is (IDLE, TXD);
+		signal state : state_t;
+		signal sel   : integer range ethernet_ii_in'low to ethernet_ii_in'high;
+	begin
+		arb : process(clk, rst) is
+		begin
+			if rst then
+
+			elsif rising_edge(clk) then
+				case state is
+					when IDLE =>
+						if mac_out.tx_active then
+							for i in ethernet_ii_in'range loop
+								if ethernet_ii_in(i).tx_en then
+									sel   <= i;
+									state <= TXD;
+									exit; -- Prioritize according to vector
+								end if;
+							end loop;
+						end if;
+
+					when TXD =>
+						state <= IDLE when (mac_in.tx_mac_data_en or mac_out.tx_active);
+				end case;
+			end if;
+		end process arb;
+
+		mac_in.tx_mac_data_en <= ethernet_ii_in(sel).tx_en;
+		mac_in.tx_mac_data    <= ethernet_ii_in(sel).tx_data;
+		txack : for i in ethernet_ii_out'range generate
+			ethernet_ii_out(i).tx_data_ack <= mac_out.tx_mac_data_ack when sel = i else '0';
+		end generate txack;
+
+		mac_in.tx_header.mac_destination <= ethernet_ii_in(sel).tx_mac_address;
+		mac_in.tx_header.mac_ethertype   <= ETHERNET_II_PROTOCOLS(sel).ethertype;
+		mac_in.tx_header.mac_source      <= config.mac_address;
+
+	end block tx;
+
+end architecture rtl;

trashernet/trashernet_pkg.vhd

@@ -29,6 +29,11 @@ package trashernet_pkg is
 	-- IP specific types
 	subtype ip_addr_t is byte_vector(0 to 3);
 
+	-- Configuration interface
+	type configuration_t is record
+		mac_address : mac_addr_t;       -- MAC address of this node
+	end record configuration_t;
+
 	-- PHY interface
 	type phy_in_t is record
 		tx_data    : byte;              -- TX Data
@@ -65,6 +70,35 @@ package trashernet_pkg is
 		rx_mac_crc_error  : std_logic;  -- End of packet, CRC invalid
 	end record mac_out_t;
 
+	-- MAC ETH interface
+	type ethernet_ii_protocol_t is record
+		ethertype : ethertype_t;
+	end record;
+	type ethernet_ii_protocol_vector is array (natural range <>) of ethernet_ii_protocol_t;
+	constant ETHERNET_II_PROTOCOLS_NONE : ethernet_ii_protocol_vector(0 to -1) := (others => (ethertype => (x"00", x"00"))); -- NULL range
+
+	type ethernet_i_out_t is record
+		tbd : std_logic;                -- TODO
+	end record;
+	type ethernet_i_in_t is record
+		tbd : std_logic;                -- TODO
+	end record;
+	constant ETHERNET_I_IN_UNUSED : ethernet_i_in_t := (others => '0'); -- TODO
+
+	type ethernet_ii_out_t is record
+		rx_mac_address : mac_addr_t;    -- Source MAC address
+		rx_data        : byte;          -- RX data
+		rx_data_valid  : std_logic;     -- RX data valid strobe
+		tx_data_ack    : std_logic;     -- Give next data byte or disable `tx_en`
+	end record;
+	type ethernet_ii_in_t is record
+		tx_mac_address : mac_addr_t;    -- Destination MAC address
+		tx_data        : byte;          -- TX data
+		tx_en          : std_logic;     -- Start and continue transmitting
+	end record;
+	type ethernet_ii_out_vector is array (natural range <>) of ethernet_ii_out_t;
+	type ethernet_ii_in_vector is array (natural range <>) of ethernet_ii_in_t;
+	constant ETHERNET_II_IN_UNUSED : ethernet_ii_in_t := (tx_mac_address => (others => x"00"), tx_data => x"00", others => '0');
 end package trashernet_pkg;
 
 package body trashernet_pkg is